Comunidad Gambas-es

Public Sub enviarmail(aTo As String[], cAsunto As String, cTexto As String, Optional cFrom As String, Optional bcc As String[], Optional adjuntos As Variant[])
 
    Dim hfile As File
    Dim archivo As String
    Dim destinatarios As String
    Dim textoplano As String
    Dim destino As String
    Dim enviador As New SmtpClient
    Dim campos As New String[]
 
    Application.busy = 1
    enviador.host = usu.mihost '"miservidor de correo"
    enviador.user = usu.miusuariodecorreo ' "miusuariodecorreo"
    enviador.password = usu.miclavedeusuariodecorreo ' "miclavedeusuariodecorreo"
 
    enviador.Encrypt = Net.SSL
    If Not cFrom Then cFrom = usu.micuentacorreo ' "micuenta@remitentedecorreo"
    enviador.Alternative = True
    enviador.Port = 465
    enviador.From = cFrom
    For Each destino In aTo
        enviador.to.Add(destino)
    Next
    enviador.Subject = cAsunto
    ' enviador.Add(cTexto, "text/plain")
    enviador.Add(cTexto, "text/html")
    Try enviador.send
    If Error Then
        Application.busy = 0
        Message.Error("No se ha podido enviar el mensaje\n" & Error.Text)
        Return
    Endif
    Application.busy = 0
    Message.Info("Mensaje enviado")
    ' Como no ha habido error, guardamos los datos de enviado
    ' para saber que se ha enviado correctamente... (persistencia)
    archivo = Settings["DATOS/basedatos"] &/ "correo/enviados.csv"
    If Not Exist(archivo) Then
        ' Aqui puede fallar sin hay mas de 1 nivel de
        ' directorio sin crear por encima de archivo.
        If Not Exist(File.Dir(archivo)) Then
 
            Print "Como no existe creamos " & File.Dir(archivo)
            Try Mkdir File.Dir(archivo)
            If Error Then Print Error.Text
 
        Endif
 
        campos.Add("fecha")
        campos.Add("destinatiarios")
        campos.Add("asunto")
        campos.Add("desde")
        campos.Add("mensaje")
        CSVwriter.create(archivo, campos)
    Else
        CSVwriter.Open(archivo)
    Endif
 
    destinatarios = aTo.Join("|")
    ' Cambio los ; del texto por } y las newline por |
    ' Al leer habrá que reconstruir
    'textoplano = Replace(cTexto, ";", "}")
    'textoplano = Replace(textoplano, gb.NewLine, "|")
    textoplano = Replace(Replace(ctexto, ";", "}"), gb.newline, "|")
    campos.Clear
    campos.Add(Format(Date(), "dd/mm/yyyy"))
    campos.Add(destinatarios)
    campos.Add(cAsunto)
    campos.Add(usu.miusuariodecorreo)
    campos.Add(textoplano)
    CSVwriter.Write(campos)
    CSVwriter.Close()
 
End