+- Comunidad Gambas-es (https://gambas-es.org)
+-- Foro: Gambas (https://gambas-es.org/forum-3.html)
+--- Foro: General (https://gambas-es.org/forum-4.html)
+--- Tema: Rellenar un array con palabras repetidas (/thread-760.html)
Rellenar un array con palabras repetidas - Shell - 11-12-2021
Buenas!.
Después de ver un ejemplo con Python, busqué algún método para rellanar un array con palabras repetidas.
Encontré el método "Fill", pero este método necesita que el array tenga dimensiones.
No puedes hacer algo como:
Código:
Dim dulces as new String[]
dulces.fill("galletas",comienza desde aquí, rellena n veces el array con la palabra "galletas")
'O también
dulces.fill("galletas", rellena n veces el array con la palabra "galletas")Y estuve probando distintas maneras de hacerlo. A ver si ustedes conocen una forma mejor que las de abajo.
Hice un test a ver cual era la más rápida.
Código:
Public Sub Main()
Randomize
TestBenchMark("LlenarArray")
TestBenchMark("LlenarArray2")
TestBenchMark("LlenarArray3")
End
Public Sub TestBenchMark(nombrefuncion As String)
Dim i, t As Float
Dim afinal As String[]
Dim ob As Object
Dim palabras As String[] = ["galletas", "merenges"]
Dim palabra As String
Dim veces As Integer
ob = Me
t = Timer
afinal = New String[]
For i = 1 To 10 ^ 6
palabra = palabras[Rand(0, palabras.Max)]
veces = Rand(1, 10)
If nombrefuncion <> "LlenarArray2" Then
afinal = Object.Call(ob, nombrefuncion, [afinal, palabra, veces])
Else
afinal.Insert(Object.Call(ob, nombrefuncion, [palabra, veces]))
Endif
Next
Print "Tiempo para 10^6 repeticiones, método: " & nombrefuncion & " = " & "\t"; Format(Timer - t, "0.######") & "s"
End
Public Function LlenarArray(apalabras As String[], palabra As String, veces As Integer) As String[]
Dim cadenaconrepeticiones As String
cadenaconrepeticiones = String(veces, palabra & " ")
apalabras.Insert(Split(cadenaconrepeticiones, " ", "'", True))
Return apalabras
End
Public Function LlenarArray2(palabra As String, veces As Integer) As String[]
Dim apalabras As New String[]
apalabras.Resize(veces)
apalabras.Fill(palabra)
Return apalabras
End
Public Function LlenarArray3(apalabras As String[], palabra As String, veces As Integer) As String[]
If apalabras.Count = 0 Then
apalabras.Resize(veces)
apalabras.Fill(palabra)
Else
apalabras.Resize(apalabras.Count + veces)
apalabras.Fill(palabra, apalabras.Count - veces, veces)
Endif
Return apalabras
EndLa respuesta fue:
Cita:Tiempo para 10^6 repeticiones, método: LlenarArray = 1,245407s
Tiempo para 10^6 repeticiones, método: LlenarArray2 = 0,960382s
Tiempo para 10^6 repeticiones, método: LlenarArray3 = 0,80571s
Os adjunto el ejemplo:
Saludos
RE: Rellenar un array con palabras repetidas - cogier - 11-12-2021
Intenta usar "Push
Código:
Public Sub Form_Open()
Dim sFood As String[] = ["biscuits", "meringues"]
Dim sArray As New String[]
Dim dTim As Date = Time(Now)
For iTimes As Integer = 0 To 2
For iFood As Integer = 0 To sFood.Max
For iArray As Integer = 0 To 10 ^ 6
sArray.Push(sFood[iFood])
Next
Next
Next
Print Format(DateDiff(dTim, Time(Now), gb.Millisecond) / 1000, "0.######") & "s"
Stop
End![[Imagen: FillArray.png]](https://www.cogier.com/gambas/FillArray.png)
RE: Rellenar un array con palabras repetidas - Shell - 11-12-2021
Gracias Cogier. Genial.
Conocía el método pop, pero no había probado el comando push, que es su inverso.
Saludos
RE: Rellenar un array con palabras repetidas - vuott - 12-12-2021
(11-12-2021, 23:47)Shell escribió: pero no había probado el comando push
No hay nada especial: ".push ()" es el método ordinario de insertar un valor en un array, aumentando así dinámicamente el número de sus elementos.
RE: Rellenar un array con palabras repetidas - Shell - 12-12-2021
(12-12-2021, 00:08)vuott escribió: No hay nada especial: ".push ()" es el método ordinario de insertar un valor en un array, aumentando así dinámicamente el número de sus elementos.
Cierto. Me temo que es el método equivalente a .add, que he usado siempre.
El código de Cogier no es exactamente igual a lo que quiero hacer. Pero ha resumido todo el funcionamiento del benchmarh en un solo procedimiento.
Ha usado una nueva forma que usa Gambas en definir la variable de control del bucle. Suelo usar la tradicional. Declaración primero.
Siempre se aprende de los compañeros.
Cogier repite un millón de veces la inserción de la primera palabra del array, luego la segunda y así hasta finalizar.
No es eso, ya que lo que busco es que el número de veces que se va a repetir cada palabra es indeterminado.
Así puede insertarse tres veces la palabra galleta y luego cinco veces la palabra merengue.
Con el benchmark ese proceso se debe repetir un millón de veces.
Usando su código, esto si es lo que quiero:
Código:
Public Sub Main()
Dim sFood As String[] = ["biscuits", "meringues"]
Dim sArray As New String[]
Dim dTim As Date = Time(Now)
Randomize
For iArray As Integer = 0 To 10 ^ 6
'Se repite n veces la primera palabra, n veces la segunda palabra
For iTimes As Integer = 0 To Rand(1, 10)
For iFood As Integer = 0 To sFood.Max
sArray.Push(sFood[iFood])
Next
Next
Next
Print Format(DateDiff(dTim, Time(Now), gb.Millisecond) / 1000, "0.######") & "s"
EndEn un I5-8400 me da este resultado: 1,025s
Es un poco más lento que el método LlenarArray2 y algo más lento con respecto a LlenarArray3.
Podía ser algo como esto:
Código:
Public Sub LlenarArray4a(palabra As String, veces As Integer) As String[]
Dim apalabras As New String[]
For i As Integer = 0 To veces - 1
apalabras.add(palabra)
Next
Return apalabras
EndY repetir eso un millón de veces. Lo que viene a decir que en vez de usar bucles es mejor usar los métodos que dispone el tipo String[]
Saludos